Mise à jour

Appliquer une mise à jour consiste à refaire l’installation avec des installateurs plus récents.

Entrez dans un compte administrateur.
Téléchargez, depuis l’Espace client de votre organisation, l’installateur complet (Antidote_12.y_B_n_Windows.exe).
Assurez-vous que les préalables sont respectés.
Exécutez l’installateur Antidote_12.y_B_n_Windows.exe.
Choisissez « Extraire » pour décompresser un dossier de la forme Antidote_12.y_B_n_Installation contenant les fichiers d’installation.
Placer tous les fichiers nécessaires sur le serveur (ou un disque accessible). Par exemple, pour une installation bilingue :

Antidote12.msi
Antidote12-Module-francais.msi
Antidote12-English-module.msi
Antidote-Connectix12.msi

Dans la séquence d’installation, il est essentiel que le fichier Antidote12.msi soit lancé en premier : l’installation de l’application Antidote 12 doit être effectuée avant l’installation des modules de langue.
Utilisez GPO pour déployer un script plutôt que les installateurs MSI directement. Ce script doit déployer les trois ou quatre MSI dans l’ordre approprié.
- GPO ne permet pas de garantir l’ordre d’installation, il est nécessaire de réaliser le déploiement à l’aide d’un script d’installation.
- Dans l’interface de GPO, assignez le script à une machine, et non à un utilisateur.
- Le script doit être déployé de façon synchrone au démarrage du poste. Ainsi, selon votre version de Windows Server, les deux politiques suivantes doivent être activées :
  Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
  Run logon scripts synchronously = Enabled
  ET
  Computer Configuration\Administrative Templates\System\Logon (ou Scripts)
  Run logon scripts asynchronously = Disabled

Voici un exemple complet d’un script de mise à jour silencieuse.

Dans cet exemple, la présence des fichiers d’Antidote 12 et de Connectix est vérifiée afin de ne lancer la mise à jour que sur les installations existantes.

@echo OFF
rem Attention ce fichier est encodé en code page DOS-850

rem Attention : Ne pas utiliser ce script pour un déploiement initial.

echo Mise à jour d'Antidote 12...

set CHEMIN_SERVEUR=\\SERVEUR\DossierAntidote
set CHEMIN_LOCAL=C:\Program Files\Druide
set CHEMIN_ANTIDOTE=%CHEMIN_LOCAL%\Antidote 12
set CHEMIN_CONNECTIX=%CHEMIN_LOCAL%\Connectix 12
set CHEMIN_LOG=%PROGRAMDATA%\Druide

mkdir "%CHEMIN_LOG%"

if not exist "%CHEMIN_ANTIDOTE%\Application\Bin64\Antidote.exe" goto OK_ANTIDOTE
if not exist "%CHEMIN_SERVEUR%\Antidote12.msi" goto OK_ANTIDOTE
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%CHEMIN_SERVEUR%\Antidote12.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauAntidote.mst;%CHEMIN_SERVEUR%\Antidote12-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logMajAntidote12.txt"
:OK_ANTIDOTE

if not exist "%CHEMIN_ANTIDOTE%\LingFR\Bin64\libLingFR.dll" goto OK_MODULE_FR
if not exist "%CHEMIN_SERVEUR%\Antidote12-Module-francais.msi" goto OK_MODULE_FR
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%CHEMIN_SERVEUR%\Antidote12-Module-francais.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote12-Module-francais-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logMajAntidote12_Module_Français.txt"
:OK_MODULE_FR

if not exist "%CHEMIN_ANTIDOTE%\LingEN\Bin64\libLingEN.dll" goto OK_MODULE_EN
if not exist "%CHEMIN_SERVEUR%\Antidote12-English-module.msi" goto OK_MODULE_EN
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%CHEMIN_SERVEUR%\Antidote12-English-module.msi" TRANSFORMS="%CHEMIN_SERVEUR%\Antidote12-English-module-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logMajAntidote12_English_Module.txt"
:OK_MODULE_EN

if not exist "%CHEMIN_CONNECTIX%\Application\Bin64\Connectix.exe" goto OK_CONNECTIX
if not exist "%CHEMIN_SERVEUR%\Antidote-Connectix12.msi" goto OK_CONNECTIX
msiexec /qn REINSTALL=ALL REINSTALLMODE=vomus /i "%CHEMIN_SERVEUR%\Antidote-Connectix12.msi" TRANSFORMS="%CHEMIN_SERVEUR%\ReseauConnectix.mst;%CHEMIN_SERVEUR%\Antidote-Connectix12-Interface-fr.mst" /l*v "%CHEMIN_LOG%\logMajAntidote12_Connectix.txt"
:OK_CONNECTIX

Déploiement en organisation

Mise à jour